Dostęp do danych historycznych: CopyHigh()
Funkcja int CopyHigh() kopiuje do tablicy najwyższe ceny (high) świec dla określonego instrumentu finansowego, określonego przedziału czasowego oraz dla określonej ilości świec. Więcej informacji można znaleźć w specyfikacji MQL4.
Należy podkreślić, że liczenie świec idzie od teraźniejszości do przeszłości, tj. bieżąca świeca ma indeks 0, wcześniejsza 1 itd. Jeśli trzeba skopiować znaną ilość danych, to najlepiej to zrobić do tablicy statycznej. Jeśli ilość danych nie jest znana, to należy kopiować do tablicy dynamicznej. Jeśli operacja kopiowania się powiedzie, funkcja zwróci ilość skopiowanych elementów, inaczej zwróci -1.
Istnieje 3 warianty funkcji:
- kopiowanie danych w oparciu o pozycję początkową i ilość elementów,
- kopiowanie danych w oparciu o datę początkową i ilość elementów,
- kopiowanie danych w oparciu o datę początkową i datę końcową.
Kopiowanie danych w oparciu o pozycję początkową i ilość elementów
Przykład 1
Przykład skryptu, gdzie do dynamicznej tablicy highArray[] skopiowano ceny high 5 świeć o indeksach od 10 do 14, dla bieżącego instrumentu finansowego _Symbol i bieżącego przedziału czasowego PERIOD_CURRENT . W tym skrypcie, po operacji ustawienia odwrotnej indeksacji, pierwszy element tablicy highArray[] o indeksie 0 będzie zawierał cenę high świecy o indeksie 10, tj. świecy z której zacznie się kopiowanie. Ostatni piąty element tablicy highArray[] o indeksie 4 - cenę high świecy o indeksie 14.
#property strict
void OnStart()
{
//---
string symbolName = _Symbol; // bieżący instrument finansowy
ENUM_TIMEFRAMES timeFrame = PERIOD_CURRENT; // bieżący przedział czasowy
int startPos = 10; // indeks świecy początkowej
int count = 5; // ilość kopiowanych świec
double highArray[]; /* tablica dynamiczna, do której
zostaną skopiowane dane */
//--- skopiować ceny high i sprawdzić czy nie wystąpił błąd
if(CopyHigh(symbolName, timeFrame, startPos, count, highArray) < 0)
{
Print("Kopiowanie CopyHigh() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- ustawić w tablicy odwrotną indeksację
ArraySetAsSeries(highArray, true);
//--- ustawić rozmiar tablicy
ArrayResize(highArray, count);
//--- wyświetlić wynik
for(int i = 0; i < count; i++)
Print("Świeca z indeksem ",startPos+i," ma cenę high = ",highArray[i]);
}
Rys. 1. Przykład stosowania funkcji CopyHigh().
Jeśli trzeba znaleźć cenę high świecy na tym wykresie notowań, gdzie program MQL4 został uruchomiony, to zalecane jest stosowanie predefiniowanej tablicy High[] .
Przykład 2
Przykład skryptu, gdzie do statycznej tablicy highArray[] skopiowano cenę high jednej świecy o indeksie 0 dla EURUSD i przedziału czasowego H1.
#property strict
void OnStart()
{
//--- tablica statyczna z 1 elementem
double highArray[1];
//--- skopiować cenę high świecy o indeksie 0 i sprawdzić czy nie wystąpił błąd
if(CopyHigh("EURUSD", PERIOD_H1, 0, 1, highArray) < 0)
{
Print("Kopiowanie CopyHigh() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- wyświetlić wynik
Print("Cena high świecy EURUSD, PERIOD_H1, indeks 0 = ",highArray[0]);
}
Rys. 2. Przykład stosowania funkcji CopyHigh().
Kopiowanie danych w oparciu o datę początkową i ilość elementów
Przykład 3
Przykład skryptu, gdzie do dynamicznej tablicy highArray[] skopiowano ceny high 3 świeć dla EURUSD i przedziału czasowego H4. Data pierwszej świecy to 2016.11.03 12:00 i jej cena high będzie znajdować się w highArray[0]. W highArray[1] cena high świecy z datą 2016.11.03 08:00, a w ostatnim trzecim elemencie tablicy highArray[2] cena high świecy 2016.11.03 04:00.
#property strict
void OnStart()
{
//---
string symbolName = "EURUSD";
ENUM_TIMEFRAMES timeFrame = PERIOD_H4;
datetime startTime = D'2016.11.03 12:00';
int count = 3;
double highArray[];
//--- skopiować ceny high i sprawdzić czy nie wystąpił błąd
if(CopyHigh(symbolName, timeFrame, startTime, count, highArray) < 0)
{
Print("Kopiowanie CopyHigh() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- ustawić w tablicy odwrotną indeksację
ArraySetAsSeries(highArray, true);
//--- ustawić rozmiar tablicy
ArrayResize(highArray, count);
//--- wyświetlić wynik
for(int i = 0; i < count; i++)
Print("highArray[",i,"] = ",highArray[i]);
}
Rys. 3. Przykład stosowania funkcji CopyHigh().
Kopiowanie danych w oparciu o datę początkową i datę końcową
Przykład 4
Przykład skryptu, gdzie do dynamicznej tablicy highArray[] skopiowano ceny high świeć dla EURUSD i przedziału czasowego H4. Data pierwszej świecy 2016.11.03 12:00, a ostatniej 2016.11.03 00:00. W tym układzie funkcja skopiuje dane dla 4 świec.
#property strict
void OnStart()
{
//---
string symbolName = "EURUSD";
ENUM_TIMEFRAMES timeFrame = PERIOD_H4;
datetime startTime = D'2016.11.03 12:00';
datetime stopTime = D'2016.11.03 00:00';
double highArray[];
//--- skopiować ceny high i sprawdzić czy nie wystąpił błąd
if(CopyHigh(symbolName, timeFrame, startTime, stopTime, highArray) < 0)
{
Print("Kopiowanie CopyHigh() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- ustawić w tablicy odwrotną indeksację
ArraySetAsSeries(highArray, true);
//--- określić ilość elementów tablicy
int highArraySize = ArraySize(highArray);
//--- ustawić rozmiar tablicy
ArrayResize(highArray, highArraySize);
//--- wyświetlić wynik
for(int i = 0; i < highArraySize; i++)
Print("highArray[",i,"] = ",highArray[i]);
}
Rys. 4. Przykład stosowania funkcji CopyHigh().
W przypadku żądania danych na podstawie dat (wariant 2 lub 3), funkcja uwzględnia czas co do sekundy. Jeśli w przykładzie 4 do daty ostatniej świecy dopisać 1 sekundę, tj. data wyglądałaby jako 2016.11.03 00:00:01 to funkcja skopiuje dane nie dla 4, a dla 3 świec (rys 5).
Rys. 5. Przykład stosowania funkcji CopyHigh().