Dostęp do danych historycznych: CopyLow()
Funkcja int CopyLow() kopiuje do tablicy najniższe ceny (low) świec dla określonego instrumentu finansowego, określonego przedziału czasowego oraz dla określonej ilości świec. Więcej informacji można znaleźć w specyfikacji MQL4.
Należy podkreślić, że liczenie świec idzie od teraźniejszości do przeszłości, tj. bieżąca świeca ma indeks 0, wcześniejsza 1 itd. Jeśli trzeba skopiować znaną ilość danych, to najlepiej to zrobić do tablicy statycznej. Jeśli ilość danych nie jest znana, to należy kopiować do tablicy dynamicznej. Jeśli operacja kopiowania się powiedzie, funkcja zwróci ilość skopiowanych elementów, inaczej zwróci -1.
Istnieje 3 warianty funkcji:
- kopiowanie danych w oparciu o pozycję początkową i ilość elementów,
- kopiowanie danych w oparciu o datę początkową i ilość elementów,
- kopiowanie danych w oparciu o datę początkową i datę końcową.
Kopiowanie danych w oparciu o pozycję początkową i ilość elementów
Przykład 1
Przykład skryptu, gdzie do dynamicznej tablicy lowArray[] skopiowano ceny low 5 świeć o indeksach od 10 do 14, dla bieżącego instrumentu finansowego _Symbol i bieżącego przedziału czasowego PERIOD_CURRENT . W tym skrypcie, po operacji ustawienia odwrotnej indeksacji, pierwszy element tablicy lowArray[] o indeksie 0 będzie zawierał cenę low świecy o indeksie 10, tj. świecy z której zacznie się kopiowanie. Ostatni piąty element tablicy lowArray[] o indeksie 4 - cenę low świecy o indeksie 14.
#property strict
void OnStart()
{
//---
string symbolName = _Symbol; // bieżący instrument finansowy
ENUM_TIMEFRAMES timeFrame = PERIOD_CURRENT; // bieżący przedział czasowy
int startPos = 10; // indeks świecy początkowej
int count = 5; // ilość kopiowanych świec
double lowArray[]; /* tablica dynamiczna, do której
zostaną skopiowane dane */
//--- skopiować ceny low i sprawdzić czy nie wystąpił błąd
if(CopyLow(symbolName, timeFrame, startPos, count, lowArray) < 0)
{
Print("Kopiowanie CopyLow() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- ustawić w tablicy odwrotną indeksację
ArraySetAsSeries(lowArray, true);
//--- ustawić rozmiar tablicy
ArrayResize(lowArray, count);
//--- wyświetlić wynik
for(int i = 0; i < count; i++)
Print("Świeca z indeksem ",startPos+i," ma cenę low = ",lowArray[i]);
}
Rys. 1. Przykład stosowania funkcji CopyLow().
Jeśli trzeba znaleźć cenę low świecy na tym wykresie notowań, gdzie program MQL4 został uruchomiony, to zalecane jest stosowanie predefiniowanej tablicy Low[] .
Przykład 2
Przykład skryptu, gdzie do statycznej tablicy lowArray[] skopiowano cenę low jednej świecy o indeksie 0 dla EURUSD i przedziału czasowego H1.
#property strict
void OnStart()
{
//--- tablica statyczna z 1 elementem
double lowArray[1];
//--- skopiować cenę low świecy o indeksie 0 i sprawdzić czy nie wystąpił błąd
if(CopyLow("EURUSD", PERIOD_H1, 0, 1, lowArray) < 0)
{
Print("Kopiowanie CopyLow() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- wyświetlić wynik
Print("Cena low świecy EURUSD, PERIOD_H1, indeks 0 = ",lowArray[0]);
}
Rys. 2. Przykład stosowania funkcji CopyLow().
Kopiowanie danych w oparciu o datę początkową i ilość elementów
Przykład 3
Przykład skryptu, gdzie do dynamicznej tablicy lowArray[] skopiowano ceny low 3 świeć dla EURUSD i przedziału czasowego H4. Data pierwszej świecy to 2016.11.03 12:00 i jej cena low będzie znajdować się w lowArray[0]. W lowArray[1] cena low świecy z datą 2016.11.03 08:00, a w ostatnim trzecim elemencie tablicy lowArray[2] cena low świecy 2016.11.03 04:00.
#property strict
void OnStart()
{
//---
string symbolName = "EURUSD";
ENUM_TIMEFRAMES timeFrame = PERIOD_H4;
datetime startTime = D'2016.11.03 12:00';
int count = 3;
double lowArray[];
//--- skopiować ceny low i sprawdzić czy nie wystąpił błąd
if(CopyLow(symbolName, timeFrame, startTime, count, lowArray) < 0)
{
Print("Kopiowanie CopyLow() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- ustawić w tablicy odwrotną indeksację
ArraySetAsSeries(lowArray, true);
//--- ustawić rozmiar tablicy
ArrayResize(lowArray, count);
//--- wyświetlić wynik
for(int i = 0; i < count; i++)
Print("lowArray[",i,"] = ",lowArray[i]);
}
Rys. 3. Przykład stosowania funkcji CopyLow().
Kopiowanie danych w oparciu o datę początkową i datę końcową
Przykład 4
Przykład skryptu, gdzie do dynamicznej tablicy lowArray[] skopiowano ceny low świeć dla EURUSD i przedziału czasowego H4. Data pierwszej świecy 2016.11.03 12:00, a ostatniej 2016.11.03 00:00. W tym układzie funkcja skopiuje dane dla 4 świec.
#property strict
void OnStart()
{
//---
string symbolName = "EURUSD";
ENUM_TIMEFRAMES timeFrame = PERIOD_H4;
datetime startTime = D'2016.11.03 12:00';
datetime stopTime = D'2016.11.03 00:00';
double lowArray[];
//--- skopiować ceny low i sprawdzić czy nie wystąpił błąd
if(CopyLow(symbolName, timeFrame, startTime, stopTime, lowArray) < 0)
{
Print("Kopiowanie CopyLow() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- ustawić w tablicy odwrotną indeksację
ArraySetAsSeries(lowArray, true);
//--- określić ilość elementów tablicy
int lowArraySize = ArraySize(lowArray);
//--- ustawić rozmiar tablicy
ArrayResize(lowArray, lowArraySize);
//--- wyświetlić wynik
for(int i = 0; i < lowArraySize; i++)
Print("lowArray[",i,"] = ",lowArray[i]);
}
Rys. 4. Przykład stosowania funkcji CopyLow().
W przypadku żądania danych na podstawie dat (wariant 2 lub 3), funkcja uwzględnia czas co do sekundy. Jeśli w przykładzie 4 do daty ostatniej świecy dopisać 1 sekundę, tj. data wyglądałaby jako 2016.11.03 00:00:01 to funkcja skopiuje dane nie dla 4, a dla 3 świec (rys 5).
Rys. 5. Przykład stosowania funkcji CopyLow().