Dostęp do danych historycznych: CopyTickVolume()
Funkcja int CopyTickVolume() kopiuje do tablicy wolumeny tick-owe (ticks) świec dla określonego instrumentu finansowego, określonego przedziału czasowego oraz dla określonej ilości świec. Więcej informacji można znaleźć w specyfikacji MQL4.
Należy podkreślić, że liczenie świec idzie od teraźniejszości do przeszłości, tj. bieżąca świeca ma indeks 0, wcześniejsza 1 itd. Jeśli trzeba skopiować znaną ilość danych, to najlepiej to zrobić do tablicy statycznej. Jeśli ilość danych nie jest znana, to należy kopiować do tablicy dynamicznej. Jeśli operacja kopiowania się powiedzie, funkcja zwróci ilość skopiowanych elementów, inaczej zwróci -1.
Istnieje 3 warianty funkcji:
- kopiowanie danych w oparciu o pozycję początkową i ilość elementów,
- kopiowanie danych w oparciu o datę początkową i ilość elementów,
- kopiowanie danych w oparciu o datę początkową i datę końcową.
Kopiowanie danych w oparciu o pozycję początkową i ilość elementów
Przykład 1
Przykład skryptu, gdzie do dynamicznej tablicy tickVolumeArray[] skopiowano wolumeny tick-owe 5 świeć o indeksach od 10 do 14, dla bieżącego instrumentu finansowego _Symbol i bieżącego przedziału czasowego PERIOD_CURRENT . W tym skrypcie, po operacji ustawienia odwrotnej indeksacji, pierwszy element tablicy tickVolumeArray[] o indeksie 0 będzie zawierał wolumen tick-owy świecy o indeksie 10, tj. świecy z której zacznie się kopiowanie. Ostatni piąty element tablicy tickVolumeArray[] o indeksie 4 - wolumen tick-owy świecy o indeksie 14.
#property strict
void OnStart()
{
//---
string symbolName = _Symbol; // bieżący instrument finansowy
ENUM_TIMEFRAMES timeFrame = PERIOD_CURRENT; // bieżący przedział czasowy
int startPos = 10; // indeks świecy początkowej
int count = 5; // ilość kopiowanych świec
long tickVolumeArray[]; /* tablica dynamiczna, do której
zostaną skopiowane dane */
//--- skopiować wolumeny tick-owe i sprawdzić czy nie wystąpił błąd
if(CopyTickVolume(symbolName, timeFrame, startPos, count, tickVolumeArray) < 0)
{
Print("Kopiowanie CopyTickVolume() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- ustawić w tablicy odwrotną indeksację
ArraySetAsSeries(tickVolumeArray, true);
//--- ustawić rozmiar tablicy
ArrayResize(tickVolumeArray, count);
//--- wyświetlić wynik
for(int i = 0; i < count; i++)
Print("Świeca z indeksem ",startPos+i," ma wolumen tick-owy = ",tickVolumeArray[i]);
}
Rys. 1. Przykład stosowania funkcji CopyTickVolume().
Jeśli trzeba znaleźć wolumen tick-owy świecy na tym wykresie notowań, gdzie program MQL4 został uruchomiony, to zalecane jest stosowanie predefiniowanej tablicy Volume[] .
Przykład 2
Przykład skryptu, gdzie do statycznej tablicy tickVolumeArray[] skopiowano wolumen tick-owy jednej świecy o indeksie 0 dla EURUSD i przedziału czasowego H1.
#property strict
void OnStart()
{
//--- tablica statyczna z 1 elementem
long tickVolumeArray[1];
//--- skopiować wolumen tick-owy świecy o indeksie 0 i sprawdzić czy nie wystąpił błąd
if(CopyTickVolume("EURUSD", PERIOD_H1, 0, 1, tickVolumeArray) < 0)
{
Print("Kopiowanie CopyTickVolume() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- wyświetlić wynik
Print("Wolumen tick-owy świecy EURUSD, PERIOD_H1, indeks 0 = ",tickVolumeArray[0]);
}
Rys. 2. Przykład stosowania funkcji CopyTickVolume().
Kopiowanie danych w oparciu o datę początkową i ilość elementów
Przykład 3
Przykład skryptu, gdzie do dynamicznej tablicy tickVolumeArray[] skopiowano wolumeny tick-owe 3 świeć dla EURUSD i przedziału czasowego H4. Data pierwszej świecy to 2016.11.03 12:00 i jej wolumen tick-owy będzie znajdować się w tickVolumeArray[0]. W tickVolumeArray[1] wolumen tick-owy świecy z datą 2016.11.03 08:00, a w ostatnim trzecim elemencie tablicy tickVolumeArray[2] wolumen tick-owy świecy 2016.11.03 04:00.
#property strict
void OnStart()
{
//---
string symbolName = "EURUSD";
ENUM_TIMEFRAMES timeFrame = PERIOD_H4;
datetime startTime = D'2016.11.03 12:00';
int count = 3;
long tickVolumeArray[];
//--- skopiować wolumeny tick-owe i sprawdzić czy nie wystąpił błąd
if(CopyTickVolume(symbolName, timeFrame, startTime, count, tickVolumeArray) < 0)
{
Print("Kopiowanie CopyTickVolume() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- ustawić w tablicy odwrotną indeksację
ArraySetAsSeries(tickVolumeArray, true);
//--- ustawić rozmiar tablicy
ArrayResize(tickVolumeArray, count);
//--- wyświetlić wynik
for(int i = 0; i < count; i++)
Print("tickVolumeArray[",i,"] = ",tickVolumeArray[i]);
}
Rys. 3. Przykład stosowania funkcji CopyTickVolume().
Kopiowanie danych w oparciu o datę początkową i datę końcową
Przykład 4
Przykład skryptu, gdzie do dynamicznej tablicy tickVolumeArray[] skopiowano wolumeny tick-owe świeć dla EURUSD i przedziału czasowego H4. Data pierwszej świecy 2016.11.03 12:00, a ostatniej 2016.11.03 00:00. W tym układzie funkcja skopiuje dane dla 4 świec.
#property strict
void OnStart()
{
//---
string symbolName = "EURUSD";
ENUM_TIMEFRAMES timeFrame = PERIOD_H4;
datetime startTime = D'2016.11.03 12:00';
datetime stopTime = D'2016.11.03 00:00';
long tickVolumeArray[];
//--- skopiować wolumeny tick-owe i sprawdzić czy nie wystąpił błąd
if(CopyTickVolume(symbolName, timeFrame, startTime, stopTime, tickVolumeArray) < 0)
{
Print("Kopiowanie CopyTickVolume() nie powiodło się. Błąd = ",GetLastError());
return;
}
//--- ustawić w tablicy odwrotną indeksację
ArraySetAsSeries(tickVolumeArray, true);
//--- określić ilość elementów tablicy
int tickVolumeArraySize = ArraySize(tickVolumeArray);
//--- ustawić rozmiar tablicy
ArrayResize(tickVolumeArray, tickVolumeArraySize);
//--- wyświetlić wynik
for(int i = 0; i < tickVolumeArraySize; i++)
Print("tickVolumeArray[",i,"] = ",tickVolumeArray[i]);
}
Rys. 4. Przykład stosowania funkcji CopyTickVolume().
W przypadku żądania danych na podstawie dat (wariant 2 lub 3), funkcja uwzględnia czas co do sekundy. Jeśli w przykładzie 4 do daty ostatniej świecy dopisać 1 sekundę, tj. data wyglądałaby jako 2016.11.03 00:00:01 to funkcja skopiuje dane nie dla 4, a dla 3 świec (rys 5).
Rys. 5. Przykład stosowania funkcji CopyTickVolume().