Funkcje wskaźników standardowych:   iBandsOnArray()

Funkcja double iBandsOnArray() zwraca wartość wskaźnika Bollinger Bands ®, obliczonego na podstawie danych z własnej tablicy. Więcej informacji można znaleźć w specyfikacji MQL4.

Przykład 1

Skrypt do wyświetlenia wartości wskaźnika iBands() obliczonego za pomocą iBandsOnArray() na danych z tablicy. Najpierw trzeba przygotować tablicę wartości, na podstawie której będzie liczony Bollinger Bands. W poniższym przykładzie została utworzona dynamiczna tablica array[], za pomocą ArrayResize() ustawiono jej rozmiar równy ilości świec na wykresie Bars , a za pomocą ArraySetAsSeries() zmieniono kierunek indeksacji elementów tablicy. Następnie, w pętli for kopiuje się ceny close dla bieżącego instrumentu finansowego _Symbol i timeframe’u PERIOD_CURRENT . Dalej funkcja iBandsOnArray() oblicza wartość wskaźnika Bollinger Bands.

#property strict
void OnStart()
  {
//---
   double array[];                // inicjalizacja dynamicznej tablicy
   ArrayResize(array, Bars);      // ustawienie rozmiaru tablicy równej ilości świec na wykresie
   ArraySetAsSeries(array, true); // odwrócenie indeksacji elementów tablicy

//---
   for(int i=0; i<Bars; i++)
      array[i]=iClose(_Symbol, PERIOD_CURRENT, i); // zapis cen close do tablicy

//---
   int    total      = 0;          /* ilość elementów tablicy do obliczenia
                                      0 - wszystkie elementy tablicy */
   int    period     = 20;         // okres średniej kroczącej
   double deviation  = 1.5;        // krotność odchylenia standardowego
   int    bandsShift = 0;          // przesunięcie wskaźnika
   int    lineMode   = MODE_UPPER; // identyfikator linii wskaźnika
   int    indexBar   = 2;          // indeks świecy
//---
   double result=iBandsOnArray(array, total, period, deviation,
                               bandsShift, lineMode, indexBar);

//---
   Print("Wartość iBandsOnArray = ",result);
  }

Rys. 1. Przykład stosowania funkcji iBandsOnArray().